{ pkgs, nixpkgs-unstable, config, lib, ... }:

let
  service = "gitea";
  cfg = config.homelab.${service};
  sec = config.sops.secrets;
  homelab = config.homelab;
in
{
  options.homelab.${service} = {
    enable = lib.mkEnableOption "enables ${service}";

    # set port options
    port = lib.mkOption {
      type = lib.types.int;
      default = 7703;
      description = "set port for ${service} (default: ${toString cfg.port}";
    };
    ssh_port = lib.mkOption {
      type = lib.types.int;
      default = 7567;
      description = "set port for ${service} (default: ${toString cfg.port}";
    };
    url = lib.mkOption {
      type = lib.types.str;
      default = "git.${homelab.base_domain}";
      description = "set domain for ${service}";
    };
    data_dir = lib.mkOption {
      type = lib.types.str;
      default = "/var/lib/${service}";
      description = "set data directory for ${service}";
    };
    ids = lib.mkOption {
      type = lib.types.int;
      default = cfg.port;
      description = "set uid and pid of ${service} user (matches port by default)";
    };
    backup = lib.mkOption {
      type = lib.types.bool;
      default = true;
      description = "enable backups for ${service}";
    };
    motd = lib.mkOption {
      type = lib.types.nullOr lib.types.str;
      default = service;
    };
  };

  config = lib.mkIf cfg.enable {
    
    # declare ${service} group
    users.groups.${service} = { gid = lib.mkForce cfg.ids; };

    # declare ${service} user
    users.users.${service} = {
      description = lib.mkForce "${service} server user";
      uid = lib.mkForce cfg.ids;
      isSystemUser = true;
      shell = pkgs.bash; 
      home = cfg.data_dir;
      createHome = true;
      group = service;
      extraGroups = [];
      # if you wanna attempt system ssh again
      #openssh.authorizedKeys.keyFiles = [
      #  "${cfg.data_dir}/.ssh/authorized_keys"
      #];
    };

    # declare the gitea service
    services.gitea = {
      enable = true;
      user = "gitea";
      group = "gitea";
      stateDir = cfg.data_dir;
      appName =  "gitea";
      settings = {
        server = {
          # http config
          ROOT_URL = "https://git.blakedheld.xyz";
          DOMAIN = "git.blakedheld.xyz";
          HTTP_PORT = cfg.port;
          # local network config
          #LOCAL_ROOT_URL = "https://git.snowbelle.lan";
          ALLOW_LOCALNETWORKS = true;
          ALLOWED_DOMAINS = "10.10.0.10";
          SKIP_TLS_VERIFY = true;
          # configure for system ssh (trying to use the systms on nix sucks)
          SSH_PORT = cfg.ssh_port;
          START_SSH_SERVER = true;
          #          SSH_PORT = 22;
          #          START_SSH_SERVER = false;
          #          SSH_ROOT_PATH = "${cfg.data_dir}/.ssh";
          #          SSH_CREATE_AUTHORIZED_KEYS_FILE = true;
          # actual git config
          DEFAULT_BRANCH = "trunk";
          ENABLE_PUSH_CREATE_USER = true;
          DEFAULT_PUSH_CREATE_PRIVATE = true;
        };
      };
      database = {
        passwordFile = "${toString config.sops.secrets."gitea_database_password".path}";
      };
    };

    # override umask to make permissions work out
    systemd.services.${service}.serviceConfig = {
      UMask = lib.mkForce "0007";
    };

    # open firewall
    networking.firewall.allowedTCPPorts = [ cfg.port cfg.ssh_port ];

    # add to caddy for reverse proxy
    services.caddy.virtualHosts."git.${homelab.public_domain}" = {
      extraConfig = ''
        reverse_proxy localhost:${toString cfg.port} {
        }
      '';
    };
    services.caddy.virtualHosts."${cfg.url}" = {
      extraConfig = ''
        tls ${sec."ssl_blakedheld_crt".path} ${sec."ssl_blakedheld_key".path}
        reverse_proxy localhost:${toString cfg.port} {
        }
      '';
    };


    # add to glance
    homelab.glance.links.services = [{
      title = service;
      url = "https://git.${homelab.public_domain}";
      error-url = "http://${homelab.host_ip}:${toString cfg.port}";
      check-url = "http://${homelab.host_ip}:${toString cfg.port}";
      icon = "di:${service}"; }];

    # manage secrets with sops
    sops.secrets = {
      "${service}_database_password" = {
        owner = service;
        group = service;
      };
    };

    # add to backups
    homelab.backups.baks = {
      ${service} = { paths = [ cfg.data_dir ]; };
    };
  };
}
